Currently,
R and
S must both be polynomial rings over the same base field.
This function first checks to see whether M will be a finitely generated R-module via F. If not, an error message describing the codimension of M/(vars of S)M is given (this is equal to the dimension of R if and only if M is a finitely generated R-module.
Assuming that it is, the push forward
F_*(M) is computed. This is done by first finding a presentation for
M in terms of a set of elements that generates
M as an
S-module, and then applying the routine
coimage to a map whose target is
M and whose source is a free module over
R.
Example: The Auslander-Buchsbaum formula
Let's illustrate the Auslander-Buchsbaum formula. First construct some rings and make a module of projective dimension 2.
i1 : R4 = ZZ/32003[a..d];
|
i2 : R5 = ZZ/32003[a..e];
|
i3 : R6 = ZZ/32003[a..f];
|
i4 : M = coker genericMatrix(R6,a,2,3)
o4 = cokernel | a c e |
| b d f |
2
o4 : R6-module, quotient of R6
|
i5 : pdim M
o5 = 2
|
Create ring maps.
i6 : G = map(R6,R5,{a+b+c+d+e+f,b,c,d,e})
o6 = map(R6,R5,{a + b + c + d + e + f, b, c, d, e})
o6 : RingMap R6 <--- R5
|
i7 : F = map(R5,R4,random(R5^1, R5^{4:-1}))
o7 = map(R5,R4,{- 10565a - 353b - 15623c - 3949d + 13150e, - 1533a - 8595b + 9929c + 6203d - 6253e, 13472a - 12507b - 4292c + 10397d - 8708e, - 6390a - 12869b - 13734c + 7679d - 3327e})
o7 : RingMap R5 <--- R4
|
The module M, when thought of as an R5 or R4 module, has the same depth, but since depth M + pdim M = dim ring, the projective dimension will drop to 1, respectively 0, for these two rings.
i8 : P = pushForward(G,M)
o8 = cokernel | c -de |
| d bc-ad+bd+cd+d2+de |
2
o8 : R5-module, quotient of R5
|
i9 : pdim P
o9 = 1
|
i10 : Q = pushForward(F,P)
3
o10 = R4
o10 : R4-module, free, degrees {0, 1, 0}
|
i11 : pdim Q
o11 = 0
|
Example: generic projection of a homogeneous coordinate ring
We compute the pushforward N of the homogeneous coordinate ring M of the twisted cubic curve in P^3.
i12 : P3 = QQ[a..d];
|
i13 : M = comodule monomialCurveIdeal(P3,{1,2,3})
o13 = cokernel | c2-bd bc-ad b2-ac |
1
o13 : P3-module, quotient of P3
|
The result is a module with the same codimension, degree and genus as the twisted cubic, but the support is a cubic in the plane, necessarily having one node.
i14 : P2 = QQ[a,b,c];
|
i15 : F = map(P3,P2,random(P3^1, P3^{-1,-1,-1}))
3 1 5 3 2 1 5
o15 = map(P3,P2,{a + 2b + 6c + 2d, -a + -b + -c + -d, -a + -b + 3c + -d})
5 2 6 4 5 3 6
o15 : RingMap P3 <--- P2
|
i16 : N = pushForward(F,M)
o16 = cokernel {0} | 29880ab+64476b2-44820ac-268128bc+257121c2 3944160a2+13700556b2-19720800ac-37441368bc+49986801c2 3802051656b3-16675225452b2c+24361827678bc2-11855408589c3 0 |
{1} | -960232a+727350b+1629105c -143376332a+106960530b+245525835c 15029002560a2-60814455592ab+37247358300b2+11075256588ac+56721473880bc-62453965995c2 6584448a3-12435664a2b+12356544ab2-5335128b3-32921064a2c+33688128abc-13795884b2c+56079984ac2-23805234bc2-31822353c3 |
2
o16 : P2-module, quotient of P2
|
i17 : hilbertPolynomial M
o17 = - 2*P + 3*P
0 1
o17 : ProjectiveHilbertPolynomial
|
i18 : hilbertPolynomial N
o18 = - 2*P + 3*P
0 1
o18 : ProjectiveHilbertPolynomial
|
i19 : ann N
3 2 2 3 2
o19 = ideal(6584448a - 12435664a b + 12356544a*b - 5335128b - 32921064a c
-----------------------------------------------------------------------
2 2 2
+ 33688128a*b*c - 13795884b c + 56079984a*c - 23805234b*c -
-----------------------------------------------------------------------
3
31822353c )
o19 : Ideal of P2
|
Note: these examples are from the original Macaulay script by David Eisenbud.