next | previous | forward | backward | up | top | index | toc | Macaulay2 web site
NoetherNormalization :: noetherNormalization

noetherNormalization -- data for Noether normalization

Synopsis

Description

The computations performed in the routine noetherNormalization use a random linear change of coordinates, hence one should expect the output to change each time the routine is executed.
i1 : R = QQ[x_1..x_4];
i2 : I = ideal(x_2^2+x_1*x_2+1, x_1*x_2*x_3*x_4+1);

o2 : Ideal of R
i3 : (f,J,X) = noetherNormalization I

                      2                   4                         2   2    
o3 = (map(R,R,{10x  + -x  + x , x , 4x  + -x  + x , x }), ideal (11x  + -x x 
                  1   9 2    4   1    1   5 2    3   2              1   9 1 2
     ------------------------------------------------------------------------
                    3     80 2 2    8   3      2       2   2       2      
     + x x  + 1, 40x x  + --x x  + --x x  + 10x x x  + -x x x  + 4x x x  +
        1 4         1 2    9 1 2   45 1 2      1 2 3   9 1 2 3     1 2 4  
     ------------------------------------------------------------------------
     4   2
     -x x x  + x x x x  + 1), {x , x })
     5 1 2 4    1 2 3 4         4   3

o3 : Sequence
The next example shows how when we use the lexicographical ordering, we can see the integrality of R/ f I over the polynomial ring in dim(R/I) variables:
i4 : R = QQ[x_1..x_5, MonomialOrder => Lex];
i5 : I = ideal(x_2*x_1-x_5^3, x_5*x_1^3);

o5 : Ideal of R
i6 : (f,J,X) = noetherNormalization I

               5                   9      9         1      1              
o6 = (map(R,R,{-x  + x  + x , x , --x  + --x  + x , -x  + --x  + x , x }),
               3 1    2    5   1  10 1   10 2    4  3 1   10 2    3   2   
     ------------------------------------------------------------------------
            5 2                  3  125 3     25 2 2   25 2           3  
     ideal (-x  + x x  + x x  - x , ---x x  + --x x  + --x x x  + 5x x  +
            3 1    1 2    1 5    2   27 1 2    3 1 2    3 1 2 5     1 2  
     ------------------------------------------------------------------------
          2           2    4     3       2 2      3
     10x x x  + 5x x x  + x  + 3x x  + 3x x  + x x ), {x , x , x })
        1 2 5     1 2 5    2     2 5     2 5    2 5     5   4   3

o6 : Sequence
i7 : transpose gens gb J

o7 = {-10} | x_2^10                                                         
     {-10} | 15x_1x_2x_5^6-150x_2^9x_5-15x_2^9+75x_2^8x_5^2+15x_2^8x_5-25x_2
     {-9}  | 15x_1x_2^2x_5^3-75x_1x_2x_5^5+15x_1x_2x_5^4+750x_2^9-375x_2^8x_
     {-9}  | 45x_1x_2^3+225x_1x_2^2x_5^2+90x_1x_2^2x_5+3750x_1x_2x_5^5-375x_
     {-3}  | 5x_1^2+3x_1x_2+3x_1x_5-3x_2^3                                  
     ------------------------------------------------------------------------
                                                                             
     ^7x_5^3-15x_2^7x_5^2+15x_2^6x_5^3-15x_2^5x_5^4+15x_2^4x_5^5+9x_2^2x_5^6+
     5-25x_2^8+125x_2^7x_5^2+50x_2^7x_5-75x_2^6x_5^2+75x_2^5x_5^3-75x_2^4x_5^
     1x_2x_5^4+150x_1x_2x_5^3+45x_1x_2x_5^2-37500x_2^9+18750x_2^8x_5+1875x_2^
                                                                             
     ------------------------------------------------------------------------
                                                                             
     9x_2x_5^7                                                               
     4+15x_2^4x_5^3+9x_2^3x_5^3-45x_2^2x_5^5+18x_2^2x_5^4-45x_2x_5^6+9x_2x_5^
     8-6250x_2^7x_5^2-3125x_2^7x_5+125x_2^7+3750x_2^6x_5^2-375x_2^6x_5-75x_2^
                                                                             
     ------------------------------------------------------------------------
                                                                             
                                                                             
     5                                                                       
     6-3750x_2^5x_5^3+375x_2^5x_5^2+75x_2^5x_5+45x_2^5+3750x_2^4x_5^4-375x_2^
                                                                             
     ------------------------------------------------------------------------
                                                                             
                                                                             
                                                                             
     4x_5^3+150x_2^4x_5^2+45x_2^4x_5+27x_2^4+135x_2^3x_5^2+81x_2^3x_5+2250x_2
                                                                             
     ------------------------------------------------------------------------
                                                                             
                                                                             
                                                                             
     ^2x_5^5-225x_2^2x_5^4+225x_2^2x_5^3+81x_2^2x_5^2+2250x_2x_5^6-225x_2x_5^
                                                                             
     ------------------------------------------------------------------------
                             |
                             |
                             |
     5+90x_2x_5^4+27x_2x_5^3 |
                             |

             5       1
o7 : Matrix R  <--- R
If noetherNormalization is unable to place the ideal into the desired position after a few tries, the following warning is given:
i8 : R = ZZ/2[a,b];
i9 : I = ideal(a^2*b+a*b^2+1);

o9 : Ideal of R
i10 : (f,J,X) = noetherNormalization I
--warning: no good linear transformation found by noetherNormalization

                                   2       2
o10 = (map(R,R,{a + b, a}), ideal(a b + a*b  + 1), {b})

o10 : Sequence
Here is an example with the option Verbose => true:
i11 : R = QQ[x_1..x_4];
i12 : I = ideal(x_2^2+x_1*x_2+1, x_1*x_2*x_3*x_4+1);

o12 : Ideal of R
i13 : (f,J,X) = noetherNormalization(I,Verbose => true)
--trying random transformation: 1
--trying with basis element limit: 5
--trying with basis element limit: 20

                3     3                  1                      5 2   3      
o13 = (map(R,R,{-x  + -x  + x , x , x  + -x  + x , x }), ideal (-x  + -x x  +
                2 1   7 2    4   1   1   5 2    3   2           2 1   7 1 2  
      -----------------------------------------------------------------------
                3 3     51 2 2    3   3   3 2       3   2      2      
      x x  + 1, -x x  + --x x  + --x x  + -x x x  + -x x x  + x x x  +
       1 4      2 1 2   70 1 2   35 1 2   2 1 2 3   7 1 2 3    1 2 4  
      -----------------------------------------------------------------------
      1   2
      -x x x  + x x x x  + 1), {x , x })
      5 1 2 4    1 2 3 4         4   3

o13 : Sequence
The first number in the output above gives the number of linear transformations performed by the routine while attempting to place I into the desired position. The second number tells which BasisElementLimit was used when computing the (partial) Groebner basis. By default, noetherNormalization tries to use a partial Groebner basis. It does this by sequentially computing a Groebner basis with the option BasisElementLimit set to predetermined values. The default values come from the following list:{5,20,40,60,80,infinity}. To set the values manually, use the option LimitList:
i14 : R = QQ[x_1..x_4]; 
i15 : I = ideal(x_2^2+x_1*x_2+1, x_1*x_2*x_3*x_4+1);

o15 : Ideal of R
i16 : (f,J,X) = noetherNormalization(I,Verbose => true,LimitList => {5,10})
--trying random transformation: 1
--trying with basis element limit: 5
--trying with basis element limit: 10

                                                                 2          
o16 = (map(R,R,{x  + 2x  + x , x , 3x  + x  + x , x }), ideal (2x  + 2x x  +
                 1     2    4   1    1    2    3   2             1     1 2  
      -----------------------------------------------------------------------
                  3       2 2       3    2           2       2          2
      x x  + 1, 3x x  + 7x x  + 2x x  + x x x  + 2x x x  + 3x x x  + x x x  +
       1 4        1 2     1 2     1 2    1 2 3     1 2 3     1 2 4    1 2 4  
      -----------------------------------------------------------------------
      x x x x  + 1), {x , x })
       1 2 3 4         4   3

o16 : Sequence
To limit the randomness of the coefficients, use the option RandomRange. Here is an example where the coefficients of the linear transformation are random integers from -2 to 2:
i17 : R = QQ[x_1..x_4];
i18 : I = ideal(x_2^2+x_1*x_2+1, x_1*x_2*x_3*x_4+1);

o18 : Ideal of R
i19 : (f,J,X) = noetherNormalization(I,Verbose => true,RandomRange => 2)
--trying random transformation: 1
--trying with basis element limit: 5
--trying with basis element limit: 20
--trying with basis element limit: 40
--trying with basis element limit: 60
--trying with basis element limit: 80
--trying with basis element limit: infinity
--trying random transformation: 2
--trying with basis element limit: 5
--trying with basis element limit: 20

                                                                     2  
o19 = (map(R,R,{2x  + 4x  + x , x , - 4x  - 4x  + x , x }), ideal (3x  +
                  1     2    4   1      1     2    3   2             1  
      -----------------------------------------------------------------------
                            3        2 2        3     2           2    
      4x x  + x x  + 1, - 8x x  - 24x x  - 16x x  + 2x x x  + 4x x x  -
        1 2    1 4          1 2      1 2      1 2     1 2 3     1 2 3  
      -----------------------------------------------------------------------
        2           2
      4x x x  - 4x x x  + x x x x  + 1), {x , x })
        1 2 4     1 2 4    1 2 3 4         4   3

o19 : Sequence

This symbol is provided by the package NoetherNormalization.

Ways to use noetherNormalization :