On a complete normal toric variety, the polyhedron associated to a Cartier divisor is a lattice polytope. Given a torus-invariant Cartier divisor on a normal toric variety, this method returns an integer matrix whose columns correspond to the vertices of the associated lattice polytope. For a non-effective Cartier divisor, this methods returns
. When the divisor is ample, the normal fan the corresponding polytope equals the fan associated to the normal toric variety.
On the projective plane, the associate polytope is either empty, a point, or a triangle.
i1 : PP2 = projectiveSpace 2;
|
i2 : vertices (-PP2_0)
|
i3 : null === vertices (- PP2_0)
o3 = true
|
i4 : vertices (0*PP2_0)
o4 = 0
2 1
o4 : Matrix ZZ <--- ZZ
|
i5 : isAmple PP2_0
o5 = true
|
i6 : V1 = vertices (PP2_0)
o6 = | 0 1 0 |
| 0 0 1 |
2 3
o6 : Matrix ZZ <--- ZZ
|
i7 : X1 = normalToricVariety V1;
|
i8 : set rays X1 === set rays PP2
o8 = true
|
i9 : max X1 === max PP2
o9 = true
|
i10 : isAmple (2*PP2_0)
o10 = true
|
i11 : V2 = vertices (2*PP2_0)
o11 = | 0 2 0 |
| 0 0 2 |
2 3
o11 : Matrix ZZ <--- ZZ
|
i12 : X2 = normalToricVariety V2;
|
i13 : rays X2 === rays X1
o13 = true
|
i14 : max X2 === max X1
o14 = true
|
On a Hirzebruch surface, the polytopes associated to non-ample Cartier divisors give rise to other normal toric varieties.
i15 : FF2 = hirzebruchSurface 2;
|
i16 : isAmple FF2_2
o16 = false
|
i17 : V3 = vertices FF2_2
o17 = | 0 1 |
| 0 0 |
2 2
o17 : Matrix ZZ <--- ZZ
|
i18 : normalToricVariety V3 -- a degenerated version of the projective line
o18 = normalToricVariety {{1, 0}, {-1, 0}} , {{0}, {1}}
o18 : NormalToricVariety
|
i19 : isDegenerate normalToricVariety V3
o19 = true
|
i20 : isAmple FF2_3
o20 = false
|
i21 : V4 = vertices FF2_3
o21 = | 0 0 2 |
| 0 1 1 |
2 3
o21 : Matrix ZZ <--- ZZ
|
i22 : normalToricVariety V4 -- a weighted projective space
o22 = normalToricVariety {{1, 0}, {-1, 2}, {0, -1}} , {{0, 1}, {0, 2}, {1, 2}}
o22 : NormalToricVariety
|
i23 : vertices FF2_1
o23 = 0
2 1
o23 : Matrix ZZ <--- ZZ
|
i24 : isAmple (FF2_2+FF2_3)
o24 = true
|
i25 : V5 = vertices (FF2_2+FF2_3)
o25 = | 0 1 0 3 |
| 0 0 1 1 |
2 4
o25 : Matrix ZZ <--- ZZ
|
i26 : normalToricVariety V5 -- isomorphic Hirzebruch surface
o26 = normalToricVariety {{1, 0}, {-1, 2}, {0, 1}, {0, -1}} , {{0, 2}, {0, 3}, {1, 2}, {1, 3}}
o26 : NormalToricVariety
|